LOGPLT Subroutine

public subroutine LOGPLT(X, N)

NAME

logplt(3f) - [M_datapac:LINE_PLOT] generate a logistic probability
plot

SYNOPSIS

   SUBROUTINE LOGPLT(X,N)

    INTEGER,intent(in) :: N
    REAL(kind=wp),intent(in) :: X(:)

DESCRIPTION

LOGPLT(3f) generates a logistic probability plot.

The prototype logistic distribution used herein has mean = 0 and
standard deviation = pi/sqrt(3). This distribution is defined for
all X and has the probability density function

    f(X) = exp(X) / (1+exp(X))

As used herein, a probability plot for a distribution is a plot
of the ordered observations versus the order statistic medians for
that distribution.

The logistic probability plot is useful in graphically testing
the composite (that is, location and scale parameters need not be
specified) hypothesis that the underlying distribution from which
the data have been randomly drawn is the logistic distribution.

If the hypothesis is true, the probability plot should be near-linear.

A measure of such linearity is given by the calculated probability
plot correlation coefficient.

INPUT ARGUMENTS

X     The vector of (unsorted or sorted) observations.

N     The integer number of observations in the vector X.
      The maximum allowable value of N for this subroutine is 7500.

OUTPUT

A one-page logistic probability plot.

EXAMPLES

Sample program:

program demo_logplt
use M_datapac, only : logplt
implicit none
! call logplt(x,y)
end program demo_logplt

Results:

AUTHOR

The original DATAPAC library was written by James Filliben of the
Statistical Engineering Division, National Institute of Standards
and Technology.

MAINTAINER

John Urban, 2022.05.31

LICENSE

CC0-1.0

REFERENCES

  • Filliben, ‘Techniques for Tail Length Analysis’, Proceedings of the Eighteenth Conference on the Design of Experiments in Army Research Development and testing (Aberdeen, Maryland, October, 1972), pages 425-450.
  • Hahn and Shapiro, Statistical Methods in Engineering, 1967, pages 260-308.
  • Johnson and Kotz, Continuous Univariate Distributions–2, 1970, pages 1-21.

Arguments

Type IntentOptional Attributes Name
real(kind=wp), intent(in) :: X(:)
integer, intent(in) :: N

Common Blocks

CAUPLT (subroutine)
CHSCDF (subroutine)
CODE (subroutine)
DECOMP (subroutine)
DEMOD (subroutine)
DEXPLT (subroutine)
EV1PLT (subroutine)
EV2PLT (subroutine)
EXPPLT (subroutine)
EXTREM (subroutine)
EXTREM (subroutine)
FREQ (subroutine)
GAMPLT (subroutine)
GEOPLT (subroutine)
HFNPLT (subroutine)
INVXWX (subroutine)
LAMPLT (subroutine)
LGNPLT (subroutine)
MEDIAN (subroutine)
norout (subroutine)
NORPLT (subroutine)
PARPLT (subroutine)
PLOTU (subroutine)
POIPLT (subroutine)
RUNS (subroutine)
SAMPP (subroutine)
SPCORR (subroutine)
TAIL (subroutine)
TPLT (subroutine)
TRIM (subroutine)
UNIPLT (subroutine)
WEIB (subroutine)
WEIPLT (subroutine)
WIND (subroutine)
"> common /BLOCK2_real64/

Type Attributes Name Initial
real :: WS(15000)

Source Code

SUBROUTINE LOGPLT(X,N)
INTEGER,intent(in) :: N
REAL(kind=wp),intent(in) :: X(:)
REAL(kind=wp) :: an, cc, hold, sum1, sum2, sum3, tau, W, wbar, WS, Y, ybar, yint, yslope
INTEGER :: i, iupper
DIMENSION Y(7500), W(7500)
COMMON /BLOCK2_real64/ WS(15000)
EQUIVALENCE (Y(1),WS(1))
EQUIVALENCE (W(1),WS(7501))
!
DATA tau/1.63473745_wp/
!
      iupper = 7500
!
!     CHECK THE INPUT ARGUMENTS FOR ERRORS
!
      IF ( N<1 .OR. N>iupper ) THEN
         WRITE (G_IO,99001) iupper
         99001    FORMAT (' ', &
         & '***** FATAL ERROR--THE SECOND INPUT ARGUMENT TO THE LOGPLT SUBROUTINE IS OUTSIDE THE ALLOWABLE (1,', &
         & I0, &
         & ') INTERVAL *****')
         WRITE (G_IO,99002) N
         99002    FORMAT (' ','***** THE VALUE OF THE ARGUMENT IS ',I0,' *****')
         RETURN
      ELSEIF ( N==1 ) THEN
         WRITE (G_IO,99003)
         99003 FORMAT (' ***** NON-FATAL DIAGNOSTIC--THE SECOND INPUT ARGUMENT TO THE LOGPLT SUBROUTINE HAS THE VALUE 1 *****')
         RETURN
      ELSE
         hold = X(1)
         DO i = 2 , N
            IF ( X(i)/=hold ) GOTO 50
         ENDDO
         WRITE (G_IO,99004) hold
         99004    FORMAT (' ', &
         &'***** NON-FATAL DIAGNOSTIC--THE FIRST  INPUT ARGUMENT (A VECTOR) TO THE LOGPLT SUBROUTINE HAS ALL ELEMENTS = ',&
         & E15.8,&
         & ' *****')
      !
      !-----START POINT-----------------------------------------------------
         !
          50      an = N
         !
         !     SORT THE DATA
         !
         CALL SORT(X,N,Y)
         !
         !     GENERATE UNIFORM ORDER STATISTIC MEDIANS
         !
         CALL UNIMED(N,W)
         !
         !     COMPUTE LOGISTIC ORDER STATISTIC MEDIANS
         !
         DO i = 1 , N
            W(i) = LOG(W(i)/(1.0_wp-W(i)))
         ENDDO
         !
         !     PLOT THE ORDERED OBSERVATIONS VERSUS ORDER STATISTICS MEDIANS.
         !     WRITE OUT THE TAIL LENGTH MEASURE OF THE DISTRIBUTION
         !     AND THE SAMPLE SIZE.
         !
         CALL PLOT(Y,W,N)
         WRITE (G_IO,99005) tau , N
         99005    FORMAT (' ','LOGISTIC PROBABILITY PLOT (TAU = ',E15.8,')',54X, 'THE SAMPLE SIZE N = ',I0)
         !
         !     COMPUTE THE PROBABILITY PLOT CORRELATION COEFFICIENT.
         !     COMPUTE LOCATION AND SCALE ESTIMATES
         !     FROM THE INTERCEPT AND SLOPE OF THE PROBABILITY PLOT.
         !     THEN WRITE THEM OUT.
         !
         sum1 = 0.0_wp
         DO i = 1 , N
            sum1 = sum1 + Y(i)
         ENDDO
         ybar = sum1/an
         wbar = 0.0_wp
         sum1 = 0.0_wp
         sum2 = 0.0_wp
         sum3 = 0.0_wp
         DO i = 1 , N
            sum1 = sum1 + (Y(i)-ybar)*(Y(i)-ybar)
            sum2 = sum2 + W(i)*Y(i)
            sum3 = sum3 + W(i)*W(i)
         ENDDO
         cc = sum2/SQRT(sum3*sum1)
         yslope = sum2/sum3
         yint = ybar - yslope*wbar
         WRITE (G_IO,99006) cc , yint , yslope
         99006    FORMAT (' ','PROBABILITY PLOT CORRELATION COEFFICIENT = ',F8.5,&
         &           5X,'ESTIMATED INTERCEPT = ',E15.8,3X,                  &
         &           'ESTIMATED SLOPE = ',E15.8)
      ENDIF

END SUBROUTINE LOGPLT