system_realpath Function

public function system_realpath(input) result(string)

NAME

   system_realpath(3f) - [M_system:FILE_SYSTEM] call realpath(3c)
                         to resolve a pathname
   (LICENSE:PD)

SYNOPSIS

   function system_realpath(input) result(output)

    character(len=*),intent(in)  :: input
    character(len=:),allocatable :: output

DESCRIPTION

    system_realpath(3f) calls the C routine realpath(3c) to obtain
    the absolute pathname of given path

OPTIONS

    INPUT     pathname to resolve

RETURN VALUE

    OUTPUT    The absolute pathname of the given input pathname.
              The pathname shall contain no components that are dot
              or dot-dot, or are symbolic links. It is equal to the
              NULL character if an error occurred.

EXAMPLE

Sample program:

program demo_system_realpath
use M_system, only : system_realpath, system_perror
implicit none
! resolve each pathname given on command line
character(len=:),allocatable :: pathi,patho
integer                      :: i
integer                      :: filename_length
   do i = 1, command_argument_count()
      ! get pathname from command line arguments
      call get_command_argument (i , length=filename_length)
      if(allocated(pathi))deallocate(pathi)
      allocate(character(len=filename_length) :: pathi)
      call get_command_argument (i , value=pathi)
      !
      ! resolve each pathname
      patho=system_realpath(pathi)
      if(patho.ne.char(0))then
         write(*,*)trim(pathi),'=>',trim(patho)
      else
         call system_perror(&
         & '*system_realpath* error for pathname '//trim(pathi)//':')
         write(*,*)trim(pathi),'=>',trim(patho)
      endif
      deallocate(pathi)
   enddo
   ! if there were no pathnames given resolve the pathname "."
   if(i.eq.1)then
      patho=system_realpath('.')
      write(*,*)'.=>',trim(patho)
   endif
end program demo_system_realpath

Example usage:

demo_system_realpath .=>/home/urbanjs/V600

cd /usr/share/man demo_system_realpath . .. NotThere .=>/usr/share/man ..=>/usr/share system_realpath error for pathname NotThere:: No such file or directory NotThere=>NotThere

Arguments

Type IntentOptional Attributes Name
character(len=*), intent(in) :: input

Return Value character(len=:), allocatable


Contents

Source Code

system_realpath

Source Code

function system_realpath(input) result(string)

! ident_3="@(#) M_system system_realpath(3f) call realpath(3c) to get pathname of current working directory"

character(len=*),intent(in)    :: input
type(c_ptr)                    :: c_output
character(len=:),allocatable   :: string
character(kind=c_char,len=1),allocatable :: temp(:)
interface
   function c_realpath(c_input) bind(c,name="my_realpath") result(c_buffer)
      import c_char, c_size_t, c_ptr, c_int
      character(kind=c_char) ,intent(in)  :: c_input(*)
      type(c_ptr)                         :: c_buffer
   end function
end interface
!-----------------------------------------------------------------------------------------------------------------------------------
   temp = str2_carr(trim(input)) ! kludge for bug in ifort (IFORT) 2021.3.0 20210609
   c_output=c_realpath(temp)
   if(.not.c_associated(c_output))then
      string=char(0)
   else
      string=C2F_string(c_output)
   endif
end function system_realpath