perror(3f) - [M_system:ERROR_PROCESSING] print error message for
last C error on stderr
(LICENSE:PD)
subroutine system_perror(prefix)
character(len=*),intent(in) :: prefix
Use system_perror(3f) to print an error message on stderr
corresponding to the current value of the C global variable errno.
Unless you use NULL as the argument prefix, the error message will
begin with the prefix string, followed by a colon and a space
(:). The remainder of the error message produced is one of the
strings described for strerror(3c).
Sample program:
program demo_system_perror
use M_system, only : system_perror,system_rmdir
implicit none
character(len=:),allocatable :: DIRNAME
DIRNAME='/NOT/THERE/OR/ANYWHERE'
! generate an error with a routine that supports errno and perror(3c)
if(system_rmdir(DIRNAME).ne.0)then
call system_perror('*demo_system_perror*:'//DIRNAME)
endif
write(*,'(a)')"That's all Folks!"
end program demo_system_perror
Expected results:
*demo_system_perror*:/NOT/THERE/OR/ANYWHERE: No such file or directory
That's all Folks!
| Type | Intent | Optional | Attributes | Name | ||
|---|---|---|---|---|---|---|
| character(len=*), | intent(in) | :: | prefix |
subroutine system_perror(prefix)
use, intrinsic :: iso_fortran_env, only : ERROR_UNIT, INPUT_UNIT, OUTPUT_UNIT ! access computing environment
! ident_14="@(#) M_system system_perror(3f) call perror(3c) to display error message"
character(len=*),intent(in) :: prefix
integer :: ios
character(kind=c_char,len=1),allocatable :: temp(:)
interface
subroutine c_perror(c_prefix) bind (C,name="perror")
import c_char
character(kind=c_char) :: c_prefix(*)
end subroutine c_perror
end interface
flush(unit=ERROR_UNIT,iostat=ios)
flush(unit=OUTPUT_UNIT,iostat=ios)
flush(unit=INPUT_UNIT,iostat=ios)
temp = str2_carr(trim(prefix)) ! kludge for bug in ifort (IFORT) 2021.3.0 20210609
call c_perror(temp)
call c_flush()
end subroutine system_perror