system_getpwuid Function

public function system_getpwuid(uid) result(uname)

NAME

system_getpwuid(3f) - [M_system:QUERY] get login name associated with a UID
(LICENSE:PD)

SYNOPSIS

function system_getpwuid(uid) result (uname)

class(*),intent(in)          :: uid    ! any INTEGER type
character(len=:),allocatable :: uname

DESCRIPTION

The system_getpwuid() function returns a string containing the user
name associated with the given UID. If no match is found it returns
a null string and sets errno to indicate the error.

OPTION

uid    UID to try to look up associated username for. Can be of any
       INTEGER type.

RETURN VALUE

uname  returns the login name.

EXAMPLE

Sample program:

program demo_system_getpwuid
use M_system, only : system_getpwuid
use M_system, only : system_getuid
use,intrinsic     :: iso_fortran_env, only : int64
implicit none
character(len=:),allocatable :: name
integer(kind=int64)              :: uid
   uid=system_getuid()
   name=system_getpwuid(uid)
   write(*,'("login[",a,"] has UID ",i0)')name,uid
end program demo_system_getpwuid

AUTHOR

John S. Urban

LICENSE

Public Domain

Arguments

Type IntentOptional Attributes Name
class(*), intent(in) :: uid

Return Value character(len=:), allocatable


Contents

Source Code

system_getpwuid

Source Code

function system_getpwuid(uid) result (uname)
class(*),intent(in)                        :: uid
character(len=:),allocatable               :: uname
   character(kind=c_char,len=1)            :: username(4097)  ! assumed long enough for any username
   integer                                 :: ierr
   integer(kind=c_long_long)               :: uid_local

interface
   function c_getpwuid(c_uid,c_username) bind(c,name="my_getpwuid") result(c_ierr)
      import c_int, c_ptr, c_char, c_long_long
      integer(kind=c_long_long),value,intent(in) :: c_uid
      character(kind=c_char),intent(out)   :: c_username(*)
      integer(kind=c_int)                  :: c_ierr
   end function c_getpwuid
end interface
!-----------------------------------------------------------------------------------------------------------------------------------
   uid_local=anyinteger_to_64bit(uid)
   ierr = c_getpwuid(uid_local,username)
   if(ierr.eq.0)then
      uname=trim(arr2str(username))
   else
      uname=''
   endif
!-----------------------------------------------------------------------------------------------------------------------------------
end function system_getpwuid