polyline2(3f) - [M_pixel:DRAW] - draw an unclosed polyline in the XY plane
(LICENSE:PD)
subroutine polyline2(arrx,arry)
integer,intent(in) :: arrx(:)
integer,intent(in),optional :: arry(:)
Given either a single array composed of pairs <x(i),y(i)> of
values defining points or an X and Y array move to first point
and draw to remaining points using current line style.
ARRX If ARRY is present, an array of X values
ARRY An optional array of Y values
Sample program:
program demo_polyline2
use M_pixel
use M_writegif, only : writegif
implicit none
integer :: transparent=0
integer :: ipaws
call prefsize(300,300)
call vinit(' ')
call ortho2(-2.0,2.0,-2.0,2.0)
call color(2)
call linewidth(100)
call polyline2([-0.5,-0.5, -0.5,+0.5, +0.5,+0.5, +0.5,-0.5])
call color(4)
call polyline2( [-1,-1,+1,+1,-1] , & ! X values
& [-1,+1,+1,-1,-1] ) ! Y values
! write gif with a transparent background
call writegif('polyline2.3m_pixel.gif',P_pixel,P_ColorMap,transparent)
call vexit()
end program demo_polyline2
John S. Urban
Public Domain
| Type | Intent | Optional | Attributes | Name | ||
|---|---|---|---|---|---|---|
| class(*), | intent(in) | :: | x(:) | |||
| class(*), | intent(in), | optional | :: | y(:) |
subroutine polyline2(x,y)
!-!use :: M_anything, only : anyscalar_to_real
class(*),intent(in) :: x(:)
class(*),intent(in),optional :: y(:)
real,allocatable :: arrx(:)
real,allocatable :: arry(:)
integer :: i
integer :: isizex
integer :: isizey
integer :: ipairs
! assuming nice data in x,y pairs
arrx=anyscalar_to_real(x)
if(present(y))then ! two arrays means X array and Y array
arry=anyscalar_to_real(y)
isizex=size(arrx)
isizey=size(arry)
ipairs=min(isizex,isizey)
if(ipairs.gt.0)then
call move2(arrx(1),arry(1))
endif
do i=2,ipairs
call draw2(arrx(i),arry(i))
enddo
else ! one array means array is <x1,y1>, <x2,y2>, <x3,y3>, ...
isizex=size(arrx)
isizey=0
ipairs=isizex/2
if(ipairs.gt.0)then
call move2(arrx(1),arrx(2))
endif
do i=3,ipairs*2,2
call draw2(arrx(i),arrx(i+1))
enddo
endif
end subroutine polyline2