ssbmv(3f) - [BLAS:SINGLE_BLAS_LEVEL2] SY:=alpha*A*SX+beta*SY, A a symmetric band matrix.
subroutine ssbmv(uplo,n,k,alpha,a,lda,x,incx,beta,y,incy)
.. Scalar Arguments ..
real,intent(in) :: alpha,beta
integer,intent(in) :: incx,incy,k,lda,n
character,intent(in) :: uplo
..
.. Array Arguments ..
real,intent(in) :: a(lda,*),x(*)
real,intent(inout) :: y(*)
..
SSBMV performs the matrix-vector operation
y := alpha*A*x + beta*y,
where alpha and beta are scalars, x and y are n element vectors and A is an n by n symmetric band matrix, with k super-diagonals.
UPLO
UPLO is CHARACTER*1
On entry, UPLO specifies whether the upper or lower
triangular part of the band matrix A is being supplied as
follows:
UPLO = 'U' or 'u' The upper triangular part of A is
being supplied.
UPLO = 'L' or 'l' The lower triangular part of A is
being supplied.
N
N is INTEGER
On entry, N specifies the order of the matrix A.
N must be at least zero.
K
K is INTEGER
On entry, K specifies the number of super-diagonals of the
matrix A. K must satisfy 0 .le. K.
ALPHA
ALPHA is REAL
On entry, ALPHA specifies the scalar alpha.
A
A is REAL array, dimension ( LDA, N )
Before entry with UPLO = 'U' or 'u', the leading ( k + 1 )
by n part of the array A must contain the upper triangular
band part of the symmetric matrix, supplied column by
column, with the leading diagonal of the matrix in row
( k + 1 ) of the array, the first super-diagonal starting at
position 2 in row k, and so on. The top left k by k triangle
of the array A is not referenced.
The following program segment will transfer the upper
triangular part of a symmetric band matrix from conventional
full matrix storage to band storage:
> DO 20, J = 1, N
> M = K + 1 - J
> DO 10, I = MAX( 1, J - K ), J
> A( M + I, J ) = matrix( I, J )
> 10 CONTINUE
> 20 CONTINUE
Before entry with UPLO = 'L' or 'l', the leading ( k + 1 )
by n part of the array A must contain the lower triangular
band part of the symmetric matrix, supplied column by
column, with the leading diagonal of the matrix in row 1 of
the array, the first sub-diagonal starting at position 1 in
row 2, and so on. The bottom right k by k triangle of the
array A is not referenced.
The following program segment will transfer the lower
triangular part of a symmetric band matrix from conventional
full matrix storage to band storage:
> DO 20, J = 1, N
> M = 1 - J
> DO 10, I = J, MIN( N, J + K )
> A( M + I, J ) = matrix( I, J )
> 10 CONTINUE
> 20 CONTINUE
LDA
LDA is INTEGER
On entry, LDA specifies the first dimension of A as declared
in the calling (sub) program. LDA must be at least
( k + 1 ).
X
X is REAL array, dimension at least
( 1 + ( n - 1 )*abs( INCX ) ).
Before entry, the incremented array X must contain the
vector x.
INCX
INCX is INTEGER
On entry, INCX specifies the increment for the elements of
X. INCX must not be zero.
BETA
BETA is REAL
On entry, BETA specifies the scalar beta.
Y
Y is REAL array, dimension at least
( 1 + ( n - 1 )*abs( INCY ) ).
Before entry, the incremented array Y must contain the
vector y. On exit, Y is overwritten by the updated vector y.
INCY
INCY is INTEGER
On entry, INCY specifies the increment for the elements of
Y. INCY must not be zero.
date:December 2016
FURTHER DETAILS
Level 2 Blas routine. The vector and matrix arguments are not referenced when N = 0, or M = 0
– Written on 22-October-1986. Jack Dongarra, Argonne National Lab. Jeremy Du Croz, Nag Central Office. Sven Hammarling, Nag Central Office. Richard Hanson, Sandia National Labs.
Online html documentation available at
http://www.netlib.org/lapack/explore-html/
| Type | Intent | Optional | Attributes | Name | ||
|---|---|---|---|---|---|---|
| character(len=1), | intent(in) | :: | uplo | |||
| integer, | intent(in) | :: | n | |||
| integer, | intent(in) | :: | k | |||
| real, | intent(in) | :: | alpha | |||
| real, | intent(in) | :: | a(lda,*) | |||
| integer, | intent(in) | :: | lda | |||
| real, | intent(in) | :: | x(*) | |||
| integer, | intent(in) | :: | incx | |||
| real, | intent(in) | :: | beta | |||
| real, | intent(inout) | :: | y(*) | |||
| integer, | intent(in) | :: | incy |
| Type | Visibility | Attributes | Name | Initial | |||
|---|---|---|---|---|---|---|---|
| integer, | public | :: | i | ||||
| integer, | public | :: | info | ||||
| integer, | public | :: | ix | ||||
| integer, | public | :: | iy | ||||
| integer, | public | :: | j | ||||
| integer, | public | :: | jx | ||||
| integer, | public | :: | jy | ||||
| integer, | public | :: | kplus1 | ||||
| integer, | public | :: | kx | ||||
| integer, | public | :: | ky | ||||
| integer, | public | :: | l | ||||
| real, | public, | parameter | :: | one | = | 1.0e+0 | |
| real, | public | :: | temp1 | ||||
| real, | public | :: | temp2 | ||||
| real, | public, | parameter | :: | zero | = | 0.0e+0 |
subroutine ssbmv(uplo,n,k,alpha,a,lda,x,incx,beta,y,incy)
implicit none
!
! -- Reference BLAS level2 routine (version 3.7.0) --
! -- Reference BLAS is a software package provided by Univ. of Tennessee, --
! -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
! December 2016
!
! .. Scalar Arguments ..
real,intent(in) :: alpha,beta
integer,intent(in) :: incx,incy,k,lda,n
character,intent(in) :: uplo
! ..
! .. Array Arguments ..
real,intent(in) :: a(lda,*),x(*)
real,intent(inout) :: y(*)
! ..
!
! =====================================================================
!
! .. Parameters ..
real one,zero
parameter (one=1.0e+0,zero=0.0e+0)
! ..
! .. Local Scalars ..
real temp1,temp2
integer i,info,ix,iy,j,jx,jy,kplus1,kx,ky,l
! ..
! .. External Functions .. LOGICAL LSAME
! ..
! .. External Subroutines .. EXTERNAL XERBLA
! ..
! .. Intrinsic Functions ..
intrinsic max,min
! ..
!
! Test the input parameters.
!
info = 0
if (.not.lsame(uplo,'U') .and. .not.lsame(uplo,'L')) then
info = 1
elseif (n.lt.0) then
info = 2
elseif (k.lt.0) then
info = 3
elseif (lda.lt. (k+1)) then
info = 6
elseif (incx.eq.0) then
info = 8
elseif (incy.eq.0) then
info = 11
endif
if (info.ne.0) then
call xerbla('SSBMV ',info)
return
endif
!
! Quick return if possible.
!
if ((n.eq.0) .or. ((alpha.eq.zero).and. (beta.eq.one))) return
!
! Set up the start points in X and Y.
!
if (incx.gt.0) then
kx = 1
else
kx = 1 - (n-1)*incx
endif
if (incy.gt.0) then
ky = 1
else
ky = 1 - (n-1)*incy
endif
!
! Start the operations. In this version the elements of the array A
! are accessed sequentially with one pass through A.
!
! First form y := beta*y.
!
if (beta.ne.one) then
if (incy.eq.1) then
if (beta.eq.zero) then
y(1:n) = zero
else
y(1:n) = beta*y(1:n)
endif
else
iy = ky
if (beta.eq.zero) then
do i = 1,n
y(iy) = zero
iy = iy + incy
enddo
else
do i = 1,n
y(iy) = beta*y(iy)
iy = iy + incy
enddo
endif
endif
endif
if (alpha.eq.zero) return
if (lsame(uplo,'U')) then
!
! Form y when upper triangle of A is stored.
!
kplus1 = k + 1
if ((incx.eq.1) .and. (incy.eq.1)) then
do j = 1,n
temp1 = alpha*x(j)
temp2 = zero
l = kplus1 - j
do i = max(1,j-k),j - 1
y(i) = y(i) + temp1*a(l+i,j)
temp2 = temp2 + a(l+i,j)*x(i)
enddo
y(j) = y(j) + temp1*a(kplus1,j) + alpha*temp2
enddo
else
jx = kx
jy = ky
do j = 1,n
temp1 = alpha*x(jx)
temp2 = zero
ix = kx
iy = ky
l = kplus1 - j
do i = max(1,j-k),j - 1
y(iy) = y(iy) + temp1*a(l+i,j)
temp2 = temp2 + a(l+i,j)*x(ix)
ix = ix + incx
iy = iy + incy
enddo
y(jy) = y(jy) + temp1*a(kplus1,j) + alpha*temp2
jx = jx + incx
jy = jy + incy
if (j.gt.k) then
kx = kx + incx
ky = ky + incy
endif
enddo
endif
else
!
! Form y when lower triangle of A is stored.
!
if ((incx.eq.1) .and. (incy.eq.1)) then
do j = 1,n
temp1 = alpha*x(j)
temp2 = zero
y(j) = y(j) + temp1*a(1,j)
l = 1 - j
do i = j + 1,min(n,j+k)
y(i) = y(i) + temp1*a(l+i,j)
temp2 = temp2 + a(l+i,j)*x(i)
enddo
y(j) = y(j) + alpha*temp2
enddo
else
jx = kx
jy = ky
do j = 1,n
temp1 = alpha*x(jx)
temp2 = zero
y(jy) = y(jy) + temp1*a(1,j)
l = 1 - j
ix = jx
iy = jy
do i = j + 1,min(n,j+k)
ix = ix + incx
iy = iy + incy
y(iy) = y(iy) + temp1*a(l+i,j)
temp2 = temp2 + a(l+i,j)*x(ix)
enddo
y(jy) = y(jy) + alpha*temp2
jx = jx + incx
jy = jy + incy
enddo
endif
endif
end subroutine ssbmv