cdotc Function

public function cdotc(n, cx, incx, cy, incy)

NAME

cdotc(3f) - [BLAS:COMPLEX_BLAS_LEVEL1] CDOTC := SUM CONJUGATE(CX) * CY (conjugated vector dot product)

SYNOPSIS

 complex function cdotc(n,cx,incx,cy,incy)

   .. Scalar Arguments ..
   integer,intent(in) ::  incx,incy,n
   ..
   .. Array Arguments ..
   complex,intent(in) ::  cx(*),cy(*)
   ..

DEFINITION

CDOTC forms the dot product of two complex vectors

   CDOTC = X^H * Y

OPTIONS

N number of elements in input vector(s) CX array, dimension ( 1 + ( N - 1 )abs( INCX ) ) INCX storage spacing between elements of CX CY array, dimension ( 1 + ( N - 1 )abs( INCY ) ) INCY storage spacing between elements of CY

AUTHORS

  • Univ. of Tennessee
  • Univ. of California Berkeley
  • Univ. of Colorado Denver
  • NAG Ltd.

date:November 2017

FURTHER DETAILS jack dongarra, linpack, 3/11/78. modified 12/3/93, array(1) declarations changed to array(*)

SEE ALSO

Online html documentation available at
http://www.netlib.org/lapack/explore-html/

Arguments

Type IntentOptional Attributes Name
integer, intent(in) :: n
complex, intent(in) :: cx(*)
integer, intent(in) :: incx
complex, intent(in) :: cy(*)
integer, intent(in) :: incy

Return Value complex


Contents

Variables

Source Code

cdotc

Variables

Type Visibility Attributes Name Initial
complex, public :: ctemp
integer, public :: i
integer, public :: ix
integer, public :: iy

Source Code

       complex function cdotc(n,cx,incx,cy,incy)
      implicit none
!
!  -- Reference BLAS level1 routine (version 3.8.0) --
!  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
!  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
!     November 2017
!
!     .. Scalar Arguments ..
      integer,intent(in) ::  incx,incy,n
!     ..
!     .. Array Arguments ..
      complex,intent(in) ::  cx(*),cy(*)
!     ..
!
!  =====================================================================
!
!     .. Local Scalars ..
      complex ctemp
      integer i,ix,iy
!     ..
!     .. Intrinsic Functions ..
      intrinsic conjg
!     ..
      ctemp = (0.0,0.0)
      cdotc = (0.0,0.0)
      if (n.le.0) return
      if (incx.eq.1 .and. incy.eq.1) then
!
!        code for both increments equal to 1
!
         do i = 1,n
            ctemp = ctemp + conjg(cx(i))*cy(i)
         enddo
      else
!
!        code for unequal increments or equal increments
!          not equal to 1
!
         ix = 1
         iy = 1
         if (incx.lt.0) ix = (-n+1)*incx + 1
         if (incy.lt.0) iy = (-n+1)*incy + 1
         do i = 1,n
            ctemp = ctemp + conjg(cx(ix))*cy(iy)
            ix = ix + incx
            iy = iy + incy
         enddo
      endif
      cdotc = ctemp
      end function cdotc